*Limpando a memória
clear

*Indicando tamanho da memória
set mem 100m

*Não interromper tabelas longas
set more off

*Colocar vírgulas e pontos no padrão brasileiro
set dp comma

*Abrindo o arquivo de log
log using "C:\curso\progs\Aula34.log", replace text

************************************
*PNAD 2007 - MINAS GERAIS
************************************
use "C:\curso\dados\dom2007MG.dta", clear

************************************
*TERRENO PRÓPRIO
************************************
gen terpro=.
replace terpro=1 if v0210==2
replace terpro=0 if v0210==4

************************************
*ÁGUA CANALIZADA
************************************
gen aguacan=.
replace aguacan=1 if v0211==1
replace aguacan=0 if v0211==3

************************************
*ÁGUA DE REDE GERAL
************************************
gen aguarg=.
replace aguarg=1 if v0213==1
replace aguarg=0 if v0213==3

************************************
*BANHEIRO NO DOMICÍLIO
************************************
gen banheiro=.
replace banheiro=1 if v0215==1
replace banheiro=0 if v0215==3

************************************
*ESCOADOURO PELA REDE GERAL
************************************
gen escoarg=.
replace escoarg=1 if v0217==1
replace escoarg=0 if v0217==2 | v0217==3 | v0217==4 | v0217==5 | v0217==6 | v0217==7
 
************************************
*LIXO COLETADO DIARIAMENTE
************************************
gen lixod=.
replace lixod=1 if v0218==1
replace lixod=0 if v0218==2 | v0218==3 | v0218==4 | v0218==5 | v0218==6
 
************************************
*ILUMINAÇÃO ELÉTRICA
************************************
gen eletrica=.
replace eletrica=1 if v0219==1
replace eletrica=0 if v0219==3 | v0219==5

************************************
*CORRELAÇÃO - PWCORR
************************************
*O comando "pwcorr" usa "pairwise deletion",
*em que cada correlação é computada
*para casos que não possuem nenhum valor em branco ("missing")
*para cada par de variáveis:
*pwcorr x y z, sig

*Sem significância estatística
pwcorr terpro aguacan aguarg banheiro escoarg lixod eletrica

*Com significância estatística
pwcorr terpro aguacan aguarg banheiro escoarg lixod eletrica, sig

************************************
*CORRELAÇÃO - CORR
************************************
*O comando "corr" usa "listwise deletion",
*em que toda matriz é calculada SOMENTE
*para casos que não possuem nenhum valor em branco ("missing")
*em nenhuma variável na lista:
*corr x y z

*Este comando é mais apropriado para análise fatorial,
*já que são considerados somente casos sem nenhum "missing"

*Não apresenta significância estatística como o "pwcorr"
*Temos somente 134 observações sem nenhum "missing"
corr terpro aguacan aguarg banheiro escoarg lixod eletrica

*Observamos que água canalizada e banheiro no domicílio
*não possuem variação

*Retiramos as variáveis acima
corr terpro aguarg escoarg lixod eletrica

************************************
*ANÁLISE FATORIAL
************************************
*Veja que a análise fatorial indica casos em que variância é zero
*Temos 134 observações
factor terpro aguacan aguarg banheiro escoarg lixod eletrica, pcf

*Retiramos a variáveis com variância igual a zero
factor terpro aguarg escoarg lixod eletrica, pcf

*Quantidade de cargas fatoriais (factor loadings)
*é automaticamente calculada com base nos autovalores (eigenvalues)
*iguais ou superiores a uma unidade (critério de Kaiser)

*As cargas fatoriais (factor loadings)
*relevantes são aquelas com valores maiores que 0,5

************************************
*ROTAÇÃO FATORIAL
************************************
*Nova matriz padrão apresenta de forma mais clara a relevância
*de cada variável em cada fator.
rotate

************************************
*TESTE KAISER-MEYER-OLKLIN
************************************
*0,5676: ruim, mas em patamar razoável (Hair et al. 2006)
estat kmo

************************************
*CRIANDO NOVAS VARIÁVEIS AUTOMATICAMENTE
************************************
predict factor1 factor2

*O problema é que cada fator leva em consideração
*todas variáveis incluídas no comando,
*mesmo que com pesos diferenciados para cada fator

************************************
*CRIANDO NOVA VARIÁVEL - FATOR 1
************************************
*Baseado nas cargas fatoriais maiores que 0,5 do fator 1
factor aguarg escoarg lixod

*Automático
predict factor11

*Manual
gen factor12=(aguarg + escoarg + lixod) / 3

************************************
*CRIANDO NOVA VARIÁVEL - FATOR 2
************************************
*Baseado nas cargas fatoriais maiores que 0,5 do fator 2
factor terpro eletrica

*Autmático
predict factor21

*Manual
gen factor22=(terpro + eletrica) / 2

************************************
*SALVANDO O LOG
************************************
log close