*Limpando a memória
clear

*Indicando tamanho da memória
set mem 100m

*Não interromper tabelas longas
set more off

*Colocar vírgulas e pontos no padrão brasileiro
set dp comma

*Abrindo o arquivo de log
log using "C:\curso\progs\svyset.log", replace text

************************************
*PNAD 2007 - MINAS GERAIS
************************************
***Abrindo banco de domicílios
***Ordenamento das variáveis para juntar com banco de pessoas
use "C:\curso\dados\dom2007MG.dta", clear
sort v0101 uf v0102 v0103
saveold "C:\curso\dados\dom2007MG.dta", replace

***Abrir o banco de pessoas
***Juntar com banco de domicílios
use "C:\curso\dados\pes2007MG.dta", clear
sort v0101 uf v0102 v0103
merge v0101 uf v0102 v0103 using "C:\curso\dados\dom2007MG.dta"

***Porque há casos de domicílios sem pessoas?
tab _merge
tab v0104 _merge
drop if _merge==2

************************************
*RENDIMENTO
************************************
*Rendimento mensal em dinheiro que recebia normalmente,
*no mês de referência,
*no trabalho principal da semana de referência
sum v9532, detail

*OLHAR DICIONÁRIO DE DADOS!!!
*Recodificando rendimento
gen renpri=.
replace renpri=v9532 if v9532!=999999999999
sum renpri, d
hist renpri

*Criando logaritmo de rendimento
gen lnrenpri=ln(renpri)
hist lnrenpri

************************************
*SEXO FEMININO
************************************
gen mulher=.
replace mulher=0 if v0302==2
replace mulher=1 if v0302==4
tab mulher v0302, missing

************************************
*SEXO MASCULINO
************************************
*Categoria zero igual a 1
*e as demais iguais a zero
gen homem=!mulher
tab homem mulher, missing

*Isso é o mesmo que...
gen homem2=~mulher
tab homem2 mulher, missing

************************************
*IDADE DO MORADOR
************************************
sum v8005, d

*OLHAR DICIONÁRIO DE DADOS!!!
*Recodificando idade do morador
gen idpia=.
replace idpia=v8005 if v8005>=15 & v8005<=64
sum idpia, d

*Idade ao quadrado
gen idquad = idpia ^ 2

************************************
*GRUPOS DE IDADE
************************************
gen idpia4=.
replace idpia4=1 if idpia>=15 & idpia<=24
replace idpia4=2 if idpia>=25 & idpia<=34
replace idpia4=3 if idpia>=35 & idpia<=49
replace idpia4=4 if idpia>=50 & idpia<=64

tab idpia idpia4, missing

************************************
*ANOS DE ESTUDO
************************************
sum v4803, d

*OLHAR DICIONÁRIO DE DADOS!!!
*Recodificando anos de estudo
gen anest=.
replace anest=v4803-1 if v4803!=17
tab v4803 anest, missing

************************************
*GRUPOS DE ANOS DE ESTUDO
************************************
gen anest3=.
replace anest3=1 if anest>=0 & anest<=4
replace anest3=2 if anest>=5 & anest<=8
replace anest3=3 if anest>=9 & anest<=15

tab anest anest3, missing

************************************
*RAÇA NEGRA
************************************
gen negra=.
replace negra=0 if v0404==2
replace negra=1 if v0404==4 | v0404==8
tab v0404 negra, missing

************************************
*RAÇA BRANCA
************************************
gen branca=.
replace branca=1 if v0404==2
replace branca=0 if v0404==4 | v0404==8
tab v0404 branca, missing

************************************
*RÓTULOS DAS VARIÁVEIS
************************************
label variable renpri   "Rendimento no trabalho principal"
label variable lnrenpri "Log do rendimento no trabalho principal"
label variable mulher   "Sexo feminino"
label variable homem    "Sexo masculino"
label variable homem2   "Sexo masculino"
label variable idpia    "Idade na população em idade ativa"
label variable idpia4   "Gupos de idade"
label variable anest    "Anos de estudo"
label variable anest3   "Grupos de anos de estudo"
label variable negra    "Raça negra"
label variable branca   "Raça branca"

************************************
*RÓTULOS DAS CATEGORIAS DAS VARIÁVEIS
************************************
label define simnao 0 "Não" 1 "Sim"
label values mulher homem negra branca simnao
tab1 mulher homem negra branca
tab1 mulher homem negra branca, nolabel

************************************
*LIMPANDO O BANCO DE DADOS
************************************
*Tamanho do banco
count

*Apagando observações
keep if renpri!=. & lnrenpri!=. & ///
        mulher!=. & homem!=. & ///
        idpia!=. & anest!=. & ///
        negra!=. & branca!=. & v4718!=.

*Tamanho do banco, após exclusão dos "missings"
count

************************************
*VARIÁVEL DEPENDENTE
************************************
sum v9532, d
hist v9532
gen lnv9532=ln(v9532)
hist lnv9532

************************************
*INDICAÇÃO DE PLANO AMOSTRAL COMPLEXO
************************************
svyset [pweight=v4729], strata(v4617) psu(v4618) singleunit(centered)

************************************
*ESTATÍSTICAS DESCRITIVAS
************************************
count
tab mulher [fweight=v4729]
svy: tab mulher

************************************
*MÉDIA DA VARIÁVEL DEPENDENTE POR CATEGORIAS DA VARIÁVEL INDEPENDENTE
************************************
svy: mean v9532, over(mulher)

************************************
*REGRESSÃO LINEAR
************************************
xi: reg lnv9532 homem i.idpia4 i.anest3 branca [aweight=v4729]
xi: svy: reg lnv9532 homem i.idpia4 i.anest3 branca

outreg2 using "C:\curso\tabelas\modelosMQOsvyset.doc", replace
outreg2 using "C:\curso\tabelas\modelosMQOsvyset.doc", append stat(beta)

log close