*Limpando a memória
clear

*Indicando tamanho da memória
set mem 600m

*World Values Survey
*Somente observações em que índice sobre
*"valores racionais: tradicional/secular" (tradrat5)
*são diferentes de missing
use "C:\DCP854B\tradrat5.dta", clear

*Distribuição normal padrão cumulativa
di normal(1.96)

*z (1,645) que separa 95% inferiores dos demais:
di invnormal(.95)

*z (1,96) que separa 2,5% inferiores dos 2,5% superiores:
di invnormal(.975)

*Uma amostra de tamanho n=23 é uma amostra aleatória simples
*selecionada de uma população normalmente distribuída.
*Ache o valor crítico t(alfa/2) correspondente a um nível de confiança de 95%.

*Valor crítico
*di invttail(n,alfa/2) = di invttail(23,0.025) = 2.0686576 = t(alfa/2)
di invttail(23,0.025)

*Se tivéssemos n=23 e t(alfa/2)=2.07, podemos calcular alfa/2:
*di ttail(n,t(alfa/2)) = di ttail(23,2.07) = 0.02493172 = alfa/2
di ttail(23,2.07)

*Veja dois arquivos pdf no site para utilizar o módulo StataQuest,
*o qual instala o comando "ztesti":
net cd http://www.stata.com
net cd quest7
net install quest1
net install quest2
net install quest3

*PROPORÇÕES (cii ; ci)

*Proporção para parâmetro binomial:
*cii #obs #succ, level(#)
*Sendo: tamanho amostral (obs);
*número de sucessos (succ);
*e nível de confiança (level).

*Intervalo de confiança padrão
cii 100 40, level(95)

*Intervalo de confiança de Wilson
cii 100 40, level(95) wilson

*Para analisar variável (x001) de banco de dados:
*Antes, variável binomial precisa ser codificada em 0/1.
gen homem=x001
replace homem=0 if x001==2

*Intervalo de confiança padrão
ci homem, binomial level(95)

*Intervalo de confiança de wilson
ci homem, binomial wilson level(95)

*Verifique que erro padrão acima (Std.Err.) é igual a
*Desvio padrão da amostra/raiz(n) = (Std.Dev)/raiz(n) abaixo:
sum homem
di .4999939/(sqrt(79946))

*MÉDIAS COM s CONHECIDO (ztesti)

*Média para população normal, sigma conhecido:
*ztesti #obs #mean #sigma #h0, level(#)
*Sendo: tamanho amostral (obs);
*média amostral (mean);
*desvio padrão populacional (sigma);
*média sob hipótese nula (h0),
*mas intervalo de confiança não será afetado por H0;
*e nível de confiança (level).
ztesti 16 24.3 6 0, level(95)

*MÉDIAS COM s DESCONHECIDO (cii ; ci)

*Média para população normal, s desconhecido:
*cii #obs #mean #sd, level(#)
*Sendo: tamanho amostral (obs);
*média amostral (mean);
*desvio padrão amostral (sd);
*e nível de confiança (level).
cii 9 4 3, level(95)

*Para analisar variável (tradrat5) do banco de dados:
*ci varname, level(#)
*Sendo: nome da variável (varname); e nível de confiança (level).
ci tradrat5, level(95)

*É possível também usar este comando
mean tradrat5

*DESVIOS PADRÕES (sdtesti ; sdtest)

*Desvio padrão para população normal:
*sdtesti #obs #mean #sd #val, level(#)
*Sendo: tamanho amostral (obs);
*média amostral (mean);
*desvio padrão amostral (sd);
*desvio padrão populacional (val);
*e nível de confiança (level).
sdtesti 40 18 5 3, level(95)

*Para analisar variável (tradrat5) do banco de dados:
*sdtest  varname==#, level(#)
*Testa se desvio padrão da variável é igual a #,
*sendo: nome da variável (varname); e nível de confiança (level).
sdtest tradrat5==1, level(95)