clear
set more off
set mem 400m

************************************
*ABRINDO JANELA DE LOG
************************************
log using "C:\DCP854B\Prog_Aula16-17.log", text replace

************************************
*WORLD VALUES SURVEY
************************************
use "C:\DCP854B\wvs1981_2008.dta", clear

*Mantendo observações em que índice sobre
*"valores racionais: tradicional/secular" (tradrat5)
*são diferentes de missing
keep if tradrat5!=.

*Salvando banco
saveold "C:\DCP854B\tradrat5.dta", replace

*Tamanho do banco
count
display _N

*Histograma
hist tradrat5, frequency
graph export "C:\DCP854B\hist_tradrat5.wmf", replace

*Estatísticas descritivas de variável contínua
sum tradrat5
sum tradrat5, d
tabstat tradrat5, s(mean sd)

*Distribuição de variável categórica
tab x001

*Estatísticas descritivas de variável contínua
*por categorias de sexo (x001)
tab x001, sum(tradrat5) mean standard

*Entendendo o peso
*Peso "s017a" é o homogeneizado
browse s002 s003 s003a s017 s017a

*Estatísticas descritivas com peso
sum tradrat5 [aweight=s017a], d

*Para calcular moda, devemos instalar módulo "mmodes"
do "C:\DCP854B\modulos\mmodes.ado"
mmodes tradrat5

************************************
*Determinação de normalidade
************************************
*Histograma com densidade normal
hist tradrat5, norm freq
graph export "C:\DCP854B\histtradrat5.wmf", replace

*Diagrama de caixa, indicando "outliers" com pontos
graph hbox tradrat5
graph export "C:\DCP854B\hboxtradrat5.wmf", replace

*Diagrama de caixa ("boxplot"), excluindo "outliers"
graph hbox tradrat5, noout

*Diagrama de caixa de "tradrat5" por sexo (x001)
graph hbox tradrat5, over(x001)

*Diagrama de caixa de "tradrat5" por estado civil (x007)
graph hbox tradrat5, over(x007)

************************************
*Gráficos quantis-normais
************************************
*O comando "qnorm" estima gráficos quantis-normais ("quantile-normal plots")
*É gerado um gráfico dos quantis da variável indicada
*pelos quantis de uma distribuição normal.
qnorm tradrat5
graph export "C:\DCP854B\qnormtradrat5.wmf", replace

*Se os resíduos possuíssem uma distribuição normal,
*os pontos ficariam em cima da linha diagonal.

************************************
*Intervalo de confiança
************************************
*Para analisar variável (x001) de banco de dados:
*Antes, variável binomial precisa ser codificada em 0/1.
tab x001
tab x001, nolabel

*Gerar variável binomial "homem":
gen homem=x001
  replace homem=0 if x001==2

*Gerar variável binomial "mulher":
gen mulher=0 if homem==1
  replace mulher=1 if homem==0

*Intervalo de confiança padrão
ci homem, binomial level(95)

*Intervalo de confiança de wilson
ci homem, binomial wilson level(95)

*Para analisar variável (tradrat5) do banco de dados:
*ci varname, level(#)
*Sendo: nome da variável (varname); e nível de confiança (level).
ci tradrat5, level(95)

*É possível também usar este comando
mean tradrat5

************************************
*Teste de hipótese de proporções
*por categorias de variáveis nominais
************************************
*Pensar que a política é importante na vida
*é maior entre homens do que entre mulheres?
tab a004
tab a004, nolabel

*Política é importante na vida
gen politica=.
  replace politica=1 if a004==1 | a004==2
  replace politica=0 if a004==3 | a004==4

*Sexo por política
tab politica homem, col nofreq chi2
tab politica homem

*Teste de hipótese
tab politica mulher, col nofreq chi2
prtest politica, by(mulher)

************************************
*Teste de hipótese de médias
*por categorias de variáveis nominais
************************************
*Índice de valores racionais (tradicional/secular)
*é maior entre homens do que entre mulheres?
tab mulher, sum(tradrat5) mean
ttest tradrat5, by(mulher)

************************************
*Teste de hipótese de variâncias
*por categorias de variáveis nominais
************************************
*Índice de valores racionais (tradicional/secular)
*possui variâncias maiores entre
*entre homens do que entre mulheres?
sdtest tradrat5, by(homem)

************************************
*Correlação de Pearson com índice secular/tradicional
*(usado para correlação entre variáveis contínuas)
************************************
*Transformar índice tradicional/secular em secular/tradicional
gen indtrad=-(tradrat5)

*Religião (a006) é muito importante
gen religiao=.
  replace religiao=0 if a006>=2 & a006<=4
  replace religiao=1 if a006==1
tab a006 religiao, missing

*Religião é muito importante
scatter indtrad a006
scatter indtrad religiao
pwcorr indtrad religiao, sig

*Acredita no céu (f054)
scatter indtrad f054
pwcorr indtrad f054, sig

*Objetivo é de fazer pais orgulhosos (d054)
gen d054inv=-d054
scatter indtrad d054inv
pwcorr indtrad d054inv, sig

*Acredita no inferno (f053)
scatter indtrad f053
pwcorr indtrad f053, sig

*Passa tampo com pessoas da igreja (a060)
gen a060inv=-a060
scatter indtrad a060inv
pwcorr indtrad a060inv, sig

************************************
*Correlação de Pearson com índice auto-expressão/sobrevivência
************************************
*Transformar índice survival/self-expression em self-expression/survival
gen indsurv=-(survself)

*Homens são melhores líderes políticos do que mulheres (d059)
gen d059inv=.
  replace d059inv=1 if d059==4
  replace d059inv=2 if d059==3
  replace d059inv=3 if d059==2
  replace d059inv=4 if d059==1
pwcorr indsurv d059inv, sig

*Não é satisfeito com situação financeira do domicílio (c006)
gen c006inv=11-c006
tab c006inv c006, nolabel
pwcorr indsurv c006inv, sig

*Mulher precisa ter filhos para se realizar (d019)
pwcorr indsurv d019, sig

************************************
*PNAD 2007 - MINAS GERAIS
************************************
use "C:\DCP854B\pes2007MG.dta", clear

************************************
*Transformação de variáveis
************************************
*Rendimento
gen renpri=.
replace renpri=v9532 if v9532!=999999999999

*Criando logaritmo de rendimento
gen lnrenpri=ln(renpri)

*Sexo
gen mulher=.
replace mulher=0 if v0302==2
replace mulher=1 if v0302==4

*Idade da população em idade ativa
gen idpia=.
replace idpia=v8005 if v8005>=15 & v8005<=64

*Anos de estudo
gen anest=.
replace anest=v4803-1 if v4803!=17

*Limpando banco de dados
keep if lnrenpri!=. & mulher!=. & idpia!=. & anest!=.

************************************
*Analisando rendimento original e idade
************************************
hist renpri
scatter renpri idpia
reg renpri idpia

*Valor predito do rendimento
predict preren
scatter preren idpia

*Resíduo do rendimento
predict resren, res
scatter resren idpia

************************************
*Analisando logaritmo do rendimento e idade
************************************
hist lnrenpri
scatter lnrenpri idpia
reg lnrenpri idpia

*Valor predito do logaritmo do rendimento
predict prelnren
scatter prelnren idpia

*Valor predito do exponencial do logaritmo do rendimento
gen preren2 = exp(prelnren)
scatter preren2 idpia

*Resíduo do logaritmo do rendimento
predict reslnren, res
scatter reslnren idpia

*******************
*TRANSFORMAÇÕES DE VARIÁVEIS
*******************
*O livro do Lawrence Hamilton ("Regression with Graphs")
*exemplifica este tipo de gráfico (pág.16).

*Lawrence Hamilton ("Regression with graphics") pág.18-19
*Y^3        q=3
*Y^2        q=2
*Y^1        q=1
*Y^0.5      q=0.5
*log(Y)     q=0
*-(Y^-0.5)  q=-0.5
*-(Y^-1)    q=-1

*De uma forma geral:
*q>1: reduz concentração à direita
*q=1: dados originais
*q<1: reduz concentração à esquerda (geralmente usamos log)

************************************
*CRIAR NOVO BANCO DE DADOS - RELAÇÕES ENTRE X E Y
************************************
*Baseado na página 459 do Triola (2008)
clear
set obs 200
egen x=seq(), from(-100) to (100)

*Linear
gen y1=1+(2*x)
scatter y1 x

*Quadrática
gen y2=(x^2)-(8*x)+18
scatter y2 x

*Logaritmo
gen y3=1+(2*ln(x))
scatter y3 x if x>0

*Exponencial
gen y4=2^x
scatter y4 x if x>90
twoway line y4 x if x>90

*Potência
gen y5=3*(x^2.5)
scatter y5 x if x>0

************************************
*FECHANDO JANELA DE LOG
************************************
log close