clear
set more off
set mem 400m

************************************
*ABRINDO JANELA DE LOG
************************************
log using "C:\DCP854B\Prog_Aula23.log", text replace

************************************
*WORLD VALUES SURVEY - LIMPANDO BANCO
************************************
use "C:\DCP854B\wvs1981_2008.dta", clear

*Mantendo observações em que índice sobre
*"valores tradicional/secular" (tradrat5)
*são diferentes de missing
keep if tradrat5!=.

*Salvando banco
saveold "C:\DCP854B\tradrat5.dta", replace

************************************
*TRANSFORMAÇÕES
************************************
*Abrindo banco
use "C:\DCP854B\tradrat5.dta", clear

*Gerar variável binomial "homem"
tab x001
tab x001, nolabel
gen homem=x001
  replace homem=0 if x001==2
tab x001 homem, missing

*Categorias de educação (x025r)
tab x025r
tab x025r, nolabel
gen educ=x025r
tab x025r educ, missing

*Estado civil (x007)
tab x007
tab x007, nolabel
gen estciv=.
  replace estciv=1 if x007==1 | x007==2 | x007==8
  replace estciv=2 if x007==3 | x007==4 | x007==5 | x007==7
  replace estciv=3 if x007==6
tab x007 estciv, missing

*Religião (a006) é muito importante
tab a006
tab a006, nolabel
gen religiao=.
  replace religiao=0 if a006>=2 & a006<=4
  replace religiao=1 if a006==1
tab a006 religiao, missing

*Acredita no céu (f054)
tab f054
tab f054, nolabel
gen ceu=f054
tab f054 ceu, missing

*Objetivo é de fazer pais orgulhosos (d054)
tab d054
tab d054, nolabel
gen pais=d054
tab d054 pais, missing

*Acredita no inferno (f053)
tab f053
tab f053, nolabel
gen inferno=f053
tab f053 inferno, missing

*Passa tempo com pessoas da igreja (a060)
tab a060
tab a060, nolabel
gen igreja=a060
tab a060 igreja, missing

************************************
*RÓTULOS DAS VARIÁVEIS
************************************
label variable tradrat5 "Índice tradicional/secular"
label variable homem    "Sexo"
label variable educ     "Escolaridade"
label variable estciv   "Estado civil"
label variable religiao "Religião é muito importante"
label variable ceu      "Acredita no céu"
label variable pais     "Fazer pais orgulhosos"
label variable inferno  "Acredita no inferno"
label variable igreja   "Tempo com pessoas da igreja"

************************************
*RÓTULOS DAS CATEGORIAS DAS VARIÁVEIS
************************************
label define homem 0 "Feminino" 1 "Masculino"
label values homem homem

label define educ 1 "Baixa" 2 "Média" 3 "Alta"
label values educ educ

label define estciv 1 "Casado" 2 "Separado" 3 "Solteiro"
label values estciv estciv

label define simnao 0 "Não" 1 "Sim"
label values religiao ceu inferno simnao

label define pais 1 "Concorda muito" 2 "Concorda" 3 "Discorda" 4 "Discorda muito"
label values pais pais

label define igreja 1 "Semanalmente" 2 "1 ou 2 vezes por semana" 3 "Algumas vezes por ano" 4 "Nunca"
label values igreja igreja

************************************
*LIMPANDO O BANCO DE DADOS
************************************
*Tamanho do banco
count

*Apagando observações
keep if homem!=. & educ!=. & estciv!=.  & religiao!=. & ///
        ceu!=.   & pais!=. & inferno!=. & igreja!=.

*Tamanho do banco, após exclusão dos "missings"
count

************************************
*VARIÁVEL DEPENDENTE (tradrat5)
************************************
*Histograma
hist tradrat5, frequency
graph export "C:\DCP854B\hist_tradrat5.wmf", replace

*Estatísticas descritivas de variável contínua
sum tradrat5, d
tabstat tradrat5, s(mean sd)

************************************
*TABELAS DE FREQUÊNCIA DAS
*VARIÁVEIS INDEPENDENTES
************************************
tab1 homem educ estciv religiao ceu pais inferno igreja

************************************
*RELAÇÃO DA VARIÁVEL DEPENDENTE
*POR CATEGORIAS DE VARIÁVEIS NOMINAIS
************************************
*Sexo (x001)
ttest tradrat5, by(homem)

*Educação (x025r)
tab educ, sum(tradrat5) mean
anova tradrat5 educ

*Estado civil (x007)
tab estciv, sum(tradrat5) mean
anova tradrat5 estciv

*Religiao (a006)
ttest tradrat5, by(religiao)

*Acredita no céu (f054)
ttest tradrat5, by(ceu)

*Objetivo é de fazer pais orgulhosos (d054)
tab pais, sum(tradrat5) mean
anova tradrat5 pais

*Acredita no inferno (f053)
ttest tradrat5, by(inferno)

*Passa tempo com pessoas da igreja (a060)
tab igreja, sum(tradrat5) mean
anova tradrat5 igreja

************************************
*INSTALAR MÓDULO "OUTREG2"
************************************
do "C:\DCP854B\modulos\outreg2.ado"

************************************
*REGRESSÃO DE MÍNIMOS QUADRADOS ORDINÁRIOS
************************************
xi: reg tradrat5 homem
outreg2 using "C:\DCP854B\modelosMQO.doc", replace

xi: reg tradrat5 homem i.educ
outreg2 using "C:\DCP854B\modelosMQO.doc", append

xi: reg tradrat5 homem i.educ i.estciv
outreg2 using "C:\DCP854B\modelosMQO.doc", append

xi: reg tradrat5 homem i.educ i.estciv religiao
outreg2 using "C:\DCP854B\modelosMQO.doc", append

xi: reg tradrat5 homem i.educ i.estciv religiao ceu
outreg2 using "C:\DCP854B\modelosMQO.doc", append

xi: reg tradrat5 homem i.educ i.estciv religiao ceu i.pais
outreg2 using "C:\DCP854B\modelosMQO.doc", append

xi: reg tradrat5 homem i.educ i.estciv religiao ceu i.pais inferno
outreg2 using "C:\DCP854B\modelosMQO.doc", append

xi: reg tradrat5 homem i.educ i.estciv religiao ceu i.pais inferno i.igreja
outreg2 using "C:\DCP854B\modelosMQO.doc", append

************************************
*TESTE F PARA VERIFICAR POSSÍVEL
*EXCLUSÃO CONJUNTA DE VARIÁVEIS
************************************
xi: reg tradrat5 homem i.educ i.estciv religiao ceu i.pais inferno i.igreja
test homem religiao ceu inferno
test _Ieduc_2 _Ieduc_3
test _Ipais_2 _Ipais_3 _Ipais_4
test _Iigreja_2 _Iigreja_3 _Iigreja_4
test _Iigreja_2 _Iigreja_3

************************************
*VARIANCE INFLATION FACTOR (VIF)
************************************
*É um fator que estima o aumento da variância,
*devido à multicolinearidade na regressão de MQO.
*Colinearidade aumenta a variância dos betas, ou seja,
*diminui significância estatística (t-teste menor).
*VIF >  5 indica multicolinearidade
*VIF > 10 indica colinearidade que tende à perfeita

*Modelo com multicolinearidade
xi: reg tradrat5 homem i.educ i.estciv religiao ceu i.pais inferno i.igreja
estat vif

*Sabemos que variância é o erro padrão ao quadrado, então
*VIF de 2,67 de "acredita no ceu" significa que o erro padrão
*do coeficiente desta variável é 1,63 vezes maior (raiz de 2,67)
*do que se esta variável não fosse correlacionada com
*outras variáveis independentes.

*******************
*GRÁFICOS DE RESÍDUOS
*******************
xi: reg tradrat5 homem i.educ i.estciv religiao ceu i.pais inferno i.igreja

*Resíduo
predict restrad, res
scatter restrad tradrat5

*******************
*GRÁFICOS DE VALORES PREDITOS
*******************
reg tradrat5 homem igreja
predict predhom if homem==1
predict predmul if homem==0

twoway (line predhom igreja) (line predmul igreja)

*******************
*MUDANDO CATEGORIAS DE REFERÊNCIA
*******************
*Escolaridade: alta como referência
char educ[omit] 3

*Estado civil: separado como referência
char estciv[omit] 2

*Objetivo é de fazer pais orgulhosos: discorda muito como referência
char pais[omit] 4

*Tempo com pessoas da igreja: nunca como referência
char igreja[omit] 4

*Modelo
xi: reg tradrat5 homem i.educ i.estciv religiao ceu i.pais inferno i.igreja

*******************
*TRANSFORMAÇÕES DE VARIÁVEIS
*******************
*O livro do Lawrence Hamilton ("Regression with Graphs")
*exemplifica este tipo de gráfico (pág.16).

*Lawrence Hamilton ("Regression with graphics") pág.18-19
*Y^3        q=3
*Y^2        q=2
*Y^1        q=1
*Y^0.5      q=0.5 (raiz quadrada)
*log(Y)     q=0
*-(Y^-0.5)  q=-0.5
*-(Y^-1)    q=-1

*De uma forma geral:
*q>1: reduz concentração à direita
*q=1: dados originais
*q<1: reduz concentração à esquerda (geralmente usamos log)

************************************
*FECHANDO JANELA DE LOG
************************************
log close